Excelformeln - FORMELN - Übersicht - Summenfunktionen (10) - Flexible Alternative zur Summierung über mehrere Tabellen

Das grosse Archiv mit 582
VBA-freien Formellösungen und Tips

Summenfunktionen (10) ->

Flexible Alternative zur Summierung über mehrere Tabellen (234)

Aufgabe
Mit der Formel
=SUMME(TabelleX:TabelleY![Adresse])

kann eine einfache Summierung über mehrere Tabellenblätter erfolgen.
Hier ist die Anordnung der Tabellen wichtig, da alle Blätter die zwischen X und y liegen summiert werden.

Mit Hilfe der Funktion SUMMEWENN kann ein Array über mehrerere Arbeitsblätter erzeugt werden, der eine flexiblere Summierung ermöglicht.

Lösung
Summe von C2 der Tabellen 1 bis 3:
{=SUMME(SUMMEWENN(INDIREKT("Tabelle"&ZEILE(1:3)&"!C2");"<1e+99"))}

Summe der gesammten Spalten A der Tabellen 1 bis 3:
{=SUMME(SUMMEWENN(INDIREKT("Tabelle"&ZEILE(1:3)&"!A:A");"<1e+99"))}

Summe aller Zahlen größer 100 der Spalte A der Tabellen 1;3 und 4
{=SUMME(SUMMEWENN(INDIREKT("Tabelle"&{1;3;4}&"!A:A");">100"))}

Ergänzung vom 05.11.2005:

Für nicht indizierbare Blattnamen können diese in einem Konstantenarray angesprochen werden, z.B.:
=SUMME(SUMMEWENN(INDIREKT("'"&{"JensF"."WF"."Boris"}&"'!A:A");">100"))
für die Summe aller Zahlen >100 in Spalte A der Blätter JensF, WF und Boris (KEINE Arrayformel).

Oder, wenn die Blattnamen in D1:D3 stehen (Array):
{=SUMME(SUMMEWENN(INDIREKT("'"&D1:D3&"'!A:A");">100"))}

Ergänzung vom 13.02.2007:
Variante von Martin Beck, wenn die Blätter die Namen Januar, Februar, ..., Dezember haben und immer nur bis zum aktuellen Monat addiert werden soll:{=SUMME(SUMME((ZEILE(1:12)<=MONAT(HEUTE()))*SUMMEWENN(INDIREKT(TEXT(DATUM(1;ZEILE(1:12);1);"MMMM")&"!A1");"<1e+99")))}

zurück