Das grosse Archiv mit 628
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   GäSTEBUCH   FORUM   LINKS 
   
Übersicht   Zauberbuch   Rätselbuch   Sparbuch   Bücher-Downloads / Errata  
 
Datum/Zeit (1) ->

Ermittlung des Ostersonntags und aller beweglichen Feiertage (3)
 
 
Aufgabe
Fast alle beweglichen Feiertage eines Jahres beziehen sich auf den Ostersonntag.
Wie wird dieser ermittelt (nach Gauß)?

       A       
1 2001  
2  
3 20  
4 18  
5 6  
6 46  
7  
8 Ostersonntag:  
9 15.04.2001 

Lösung
Die Jahreszahl steht in Zelle A1

1. Kurzform
Gilt nur nach 1900. Die frühere Microsoft-Obergrenze von 2079 schien aufgehoben; - just aber für dieses Jahr sind die Kurzfassungen falsch - und ab dem Jahre 2204 sind sie sowieso reif für die Tonne. Zur Sicherheit also immer die Gauß-Version nehmen.

=RUNDEN((TAG(MINUTE(A1/38)/2+55)&".4."&A1)/7;)*7-6

Ergänzung (der Autor wollte, dass sein Name entfernt wird):
=7*RUNDEN((4&-A1)/7+REST(19*REST(A1;19)-7;30)*0,14;)-6
berechnet auch das Jahr 2079 korrekt.

Obige Kurzformel bei 1904-Datumswerten mit -5 (statt -6) am Schluß funktioniert nicht in 1954 - 1961 - 1981 - 2005; es wird also länger zu:
=DATUM(A1;3;28)+REST(24-REST(A1;19)*10,63;29)-REST(KÜRZEN(A1*5/4)+REST(24-REST(A1;19)*10,63;29)+1;7)

2. Lösung nach Gauß (perfekt - also ohne excelspezifische Datumsfunktionen)
Gilt zwischen 532 (Ostertafeln des Dyonysius Exiguus) und 8702

in A3 steht =GANZZAHL(A1/100)
in A4 steht =REST(19*REST(A1;19)+A3-GANZZAHL(A3/4)-GANZZAHL((A3-GANZZAHL((A3+8)/25)+1)/3)+15;30)
in A5 steht =REST(32+2*REST(A3;4)+2*GANZZAHL(REST(A1;100)/4)-A4-REST(REST(A1;100);4);7)
in A6 steht =A4+A5-7*GANZZAHL((REST(A1;19)+11*A4+22*A5)/451)+22

=TEXT(WENN(A6-31 < 1;A6;A6-31);"0#")&"."&WENN(A6 > 31;"04.";"03.")&A1

Steht das so ermittelte Datum (nach 1900) in Zelle H4, ergeben sich die anderen Feiertage mit:
=H4-52 Altweiber
=H4-48 Rosenmontag
=H4-2 Karfreitag
=H4+1 Ostermontag
=H4+39 Himmelfahrt
=H4+49 Pfingstsonntag
=H4+50 Pfingstmontag
=H4+60 happy cadaver

(Die von Weihnachten abhängigen Feiertage findest Du in Formel Nr. 299)

Helmut Mittelbach:
Gibst Du in D1 ein Datum ein (formatiert TT.MM), liefert Dir folgende Formel (Zellformat JJJJ;;) das Jahr, wann bis zur Jahreszahl in A1 das letzte mal ein Ostersonntag auf dieses Datum fiel. (Funktioniert ab 1900 - Ostern am 22.03. war letztmals im Jahr 1818)

{=MAX((KÜRZEN(DATUM(ZEILE(INDIREKT(1900&":"&A1));3;56-REST(REST(ZEILE(INDIREKT(1900&":"&A1));19)*10,63+5;29))/7)*7+1=DATUM(ZEILE(INDIREKT(1900 & ":" & A1));MONAT(D1);TAG(D1)))*(KÜRZEN(DATUM(ZEILE(INDIREKT(1900&":"&A1));3;56-REST(REST(ZEILE(INDIREKT(1900&":"&A1));19)*10,63+5;29))/7)*7+1))}

Alle Ostersonntage zwischen 1750 und 2400 mit Auflistung per individuellem Tagesdatum
DOWNLOAD

Erläuterung
Der Ostertermin (Bandbreite: 22.03. - 25.04. / die nächsten im Jahre 2285 und 2038)
ist auf den ersten Sonntag nach dem ersten Vollmond nach Frühlingsanfang festgelegt worden (1. Konzil von Nizäa (325 n. Chr.). Ostern sollte auf den Tag fallen, an dem der Himmel sich verdunkelt (wenigstens Neumond, wenn schon keine Sonnenfinsternis).
Zwischen Ost- und Westkirche gab es schon damals einen Sonntags-Streit. Die Berechnung erfolgt in den orthodoxen Kirchen nach dem julianischen, in den übrigen Kirchen nach dem gregorianischen Kalender.

Kalender
selbst heißt ursprünglich: erster Tag das Monats und bezieht sich auf das Mondjahr = 12 Mondumläufe.
Das Mondjahr ist 11 Tage kürzer als das Sonnenjahr. Um das auszugleichen, hatte das Jahr mal 12 mal 13 Monate. Viele Völker sind so verfahren.

Der julianische Kalender
löst das Mondjahr ab und bezieht sich auf das Sonnenjahr mit 365,25 Tagen und gleicht die auflaufende Differenz mit einem Schalttag alle 4 Jahre aus (29.Februar).
(Julianisch weil = eingeführt durch Julius Cäsar, 46 v. Chr.).
Das Wort Monat bezogen auf den Mondkalender wird in den allermeisten Sprachen beibehalten. Der Bezug zum Mondjahr geht aber verloren. Rechnerisch zumindest. Die Maßzahl 365,25 ist aber zu groß. Richtig wäre nach heutigem Stand etwa 365,2422.

Der gregorianische Kalender
macht 1582 einen Sprung vom 4.Oktober auf den 15. Oktober (Papst Gregor XIII.), um damit auch die Restdifferenz von 11 min. + 12 sec. jährlich auszugleichen. Der alle 4 Jahre anfallende Schalttag des julianischen Kalenders fällt bei vollen Jahrhunderten aus. Ausnahme: die durch 400 teilbaren.

Exaktes Sonnenjahr
Ein Gregorjahr dauert im Schnitt 365 Tage / 5 Stunden / 49 Minuten / 12 Sekunden =365,2425
Exakt sind's: 365 / 5 / 48 / 45,252 =365,242190417 - ergo haben wir 26,748 Sekunden zuviel p.a.
Nach ca. 3.230 Jahren macht das einen Tag aus. Im Jahr 4812 brauchen wir also wieder einen Papst, den das nervt.


Alles klar, Zeitgenossen des christlichen Abendlandes im Jahr 2002 nach Christus?

Warum eigentlich Christus? Der hieß doch Jesus. Christus ist nur ein Zusatz zu dem Namen Jesus. Jesus Christus heißt also: Jesus, der Gesalbte.
Wir haben also u.a. eine "gesalbte" Volkspartei.
Gesalbt oder geschmiert - wo ist da schon der Unterschied ...
(von irgendeinem Heiner)

 
    zurück


 
powered by telltarget