Das grosse Archiv mit 627
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   GäSTEBUCH   FORUM   LINKS 
   
Übersicht   Zauberbuch   Rätselbuch   Sparbuch   Bücher-Downloads / Errata  
 
Summenfunktionen (9) ->

SUMMEWENN mit mehreren Bedingungen / über mehrere Spalten (61)
 
 
Aufgabe
Die Funktion SUMMEWENN durchsucht nur eine Spalte nach einem Suchkriterium.
Wenn alle Zeilen summiert werden sollen, bei denen in der 1. Spalte ein bestimmtes Suchkriterium steht UND in der 2. Spalte ein weiteres, versagt SUMMEWENN genauso wie bei mehreren zu summierenden Spalten.

       A               B               C       
1 831  
2 750  
3 x  y  782  
4 751  
5 619  
6 x  y  345  
7 658  
8 691  
9 x  y  524  
10 297  
11      
12 Summe  1651   

Lösung
Zu durchsuchende Spalten: A und B
zu summierende Spalte: C

{=SUMME(WENN((A1:A100="x");WENN(B1:B100="y";C1:C100)))}

oder
{=SUMME(WENN((A1:A100="x")*(B1:B100="y");C1:C100))}

oder kürzer ohne WENN
{=SUMME((A1:A100="x")*(B1:B100="y")*C1:C100)}

oder noch kürzer durch Verkettung
{=SUMME((A1:A100&B1:B100="x"&"y")*C1:C100)}

Achtung: Steht in A nichts und in B "xy" liefert diese Variante auch einen Treffer. Dies könnte man mit einem Trennzeichen unterbinden:
{=SUMME((A1:A100&"#"&B1:B100="x"&"#"&"y")*C1:C100)}
Das benutzte Trennzeichen sollte aber selbst nicht in Spalte A oder B vorkommen.

oder ohne Eingabe als Array-Formel
=SUMMENPRODUKT((A1:A100="x")*(B1:B100="y")*C1:C100)

Durch die Multiplikation bzw. Verkettung sind natürlich auch mehr als 2 Bedingungen kombinierbar.

Vorsicht: In den Varianten 3 bis 5 darf im Bereich C1:C100 keine Textzelle vorkommen.
Gibt es z.B. in C1 eine Überschrift, darf der Bezug in A, B und C erst in Zeile 2 beginnen.

Und nur die Variante 1 darf genommen werden, wenn in Spalte B z.B. Datumswerte und Texte stehen und nach einem bestimmten Monat selektiert werden soll:
{=SUMME(WENN((A1:A100="x");WENN(MONAT(B1:B100)=9;C1:C100)))}

Erläuterung
SUMMEWENN über mehrere Spalten funktioniert auch nicht.
=SUMMEWENN(A1:A100;"x";B1:D100)
summiert nur die entsprechenden Werte aus Spalte B; - die aus C und D nicht.

mit
{=SUMME((A1:A100="x")*B1:D100)}
und allen anderen Varianten: nullo problemo.


NEU in Excel 2007:
Summe, wenn in Spalte A ein x steht und in Spalte B ein y:
=SUMMEWENNS(C:C;A:A;"x";B:B;"y") => 1651

Das geht natürlich nach wie vor auch als Arrayformel, nur dass man jetzt ganze Spalten angeben kann:
{=SUMME(WENN((A:A="x")*(B:B="y");C:C))} => 1651
 
    zurück


 
powered by telltarget