Das grosse Archiv mit 638
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   FORUM   LINKS 
   
Übersicht   Zauberbuch   Rätselbuch   Sparbuch   Bücher-Downloads / Errata  
 
Textfunktionen (2) ->

komplette Pfadangabe / Teilpfad / Ordnername / Dateiname / Blattname (95)
 
 
Aufgabe
Du willst Informationen (Namen) über Pfad, Datei und Arbeitsblatt erhalten.

Lösung
kompletter Dateipfad bis zum Arbeitsblatt:
X:\EXCEL\Daten\[statistik.xls]Diagramme
=ZELLE("Dateiname";$A$1)

Dateipfad bis zum Dateinamen ohne die [eckigen Klammern]:
X:\EXCEL\Daten\statistik.xls
=WECHSELN(LINKS(ZELLE("Dateiname";$A$1);-1+FINDEN("]";ZELLE("Dateiname";$A$1)));"[";"")

Nur Verzeichnispfad:
X:\EXCEL\Daten
=LINKS(ZELLE("Dateiname";$A$1);FINDEN("[";ZELLE("Dateiname";$A$1))-2)

Name des Ordners
Daten
=TEIL(ZELLE("Dateiname";$A$1);FINDEN("#";WECHSELN(ZELLE("Dateiname";$A$1);"\";"#";LÄNGE(ZELLE("Dateiname";$A$1))-LÄNGE(WECHSELN(ZELLE("Dateiname";$A$1);"\";))-1))+1;FINDEN("\";TEIL(ZELLE("dateiname";$A$1);FINDEN("#";WECHSELN(ZELLE("Dateiname";$A$1);"\";"#";LÄNGE(ZELLE("Dateiname";$A$1))-LÄNGE(WECHSELN(ZELLE("Dateiname";$A$1);"\";))-1))+1;90))-1)

Pfad vor dem Ordner:
X:\EXCEL\
=LINKS(ZELLE("Dateiname";A1);FINDEN("#";WECHSELN(ZELLE("Dateiname";A1);"\";"#";LÄNGE(ZELLE("Dateiname";A1))-LÄNGE(WECHSELN(ZELLE("Dateiname";A1);"\";))-1)))

Name der Datei:
statistik.xls
=TEIL(ZELLE("Dateiname";$A$1);FINDEN("[";ZELLE("Dateiname";$A$1))+1;FINDEN("]";ZELLE("Dateiname";$A$1))-FINDEN("[";ZELLE("Dateiname";$A$1))-1)
Nur statistik (ohne .xls): hinten -1 durch -5 ersetzen (xlsx -6).

Name des Arbeitsblattes:
Diagramme
=TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+1;31)

Ab Excel-2013 kann man letzteres kombinieren mit den Funktionen Blatt und Blätter.
=TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+1;99)&" ist Blatt Nr. "&BLATT(TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+1;99))&" von "&BLÄTTER()&" insgesamt."
ergibt z.B.: Diagramme ist Blatt Nr. 4 von 11 insgesamt.


Hinweise:
Die Formeln funktionieren nur in bereits gespeicherten Dateien.
Schreibt man überall lediglich ZELLE("Dateiname") - also ohne ;$A$1 - wird der Pfad zur zuletzt berechneten Tabelle angezeigt.

Erläuterung
Falls die Formeln auch in anderssprachigen Versionen funktionieren müssen, ersetzt "Dateiname" durch "Filename". Das ist in allen Sprachen (auch deutsch) gültig.
 
    zurück


 
powered by telltarget