Das grosse Archiv mit 636
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   FORUM   LINKS 
   
 
Diagramme (1) ->

Nicht ganz normale Datenreihen
 
 
Aufgabe
Darstellung von besonderen Datenreihen in einem Punkt(XY)-Diagramm mit definierten Namen und den Funktionen TEILERGEBNIS und BEREICH.VERSCHIEBEN.


-kumulierte Werte
-Jeden x-ten Wert darstellen
-eine Diagonale
-eine zweidimensionale Tabelle
(alles ohne Hilfsspalten!)



Lösung
Speichere eine Mappe als Mappe1.xls und lege ein Punkt(XY)-Diagramm an.

In A1:D10 stehen Werte.

Darstellung im Diagramm:

1. kumulierte Werte von A1:A5:
Name:kumuliert
bezieht sich auf: =TEILERGEBNIS(9;BEREICH.VERSCHIEBEN(Tabelle1!$A$1;;;ZEILE(indirekt("Tabelle1!$1:$5"))))
Datenreihe: =DATENREIHE("Kumuliert";;Mappe1.xls!kumuliert;1)
(Beliebige Werte ins Diagramm ziehen und DATENREIHE entsprechend überschreiben)

2. jede zweite Zeile, also A1;A3;A5;A7;A9
Name:jedezweite
bezieht sich auf: =TEILERGEBNIS(9;BEREICH.VERSCHIEBEN(Tabelle1!$A$1;(-1+ZEILE(indirekt("Tabelle1!$1:$5")))*2;))
Datenreihe: =DATENREIHE("JedeZweite";;Mappe1.xls!jedeZweite;2)

3. Eine Diagonale, also A1;B2;C3;D4
Name:diagonal
bezieht sich auf: =TEILERGEBNIS(9;BEREICH.VERSCHIEBEN(Tabelle1!$A$1;ZEILE(Tabelle1!$1:$4)-1;ZEILE(indirekt("Tabelle1!$1:$4"))-1))
Datenreihe: =DATENREIHE("Diagonal";;Mappe1.xls!diagonal;3)

4. Die Tabelle A1:C3
Name:tab
bezieht sich auf: =TEILERGEBNIS(9;BEREICH.VERSCHIEBEN(Tabelle1!$A$1;(-1+ZEILE(indirekt("Tabelle1!$1:$9")))/3;REST(ZEILE(indirekt("Tabelle1!$1:$9"))-1;3)))
Datenreihe: =DATENREIHE("Tabelle";;Mappe1.xls!tab;4)
Erläuterung
Siehe dazu auch die Weiterentwicklung in

Formel Nr.340





 
    zurück


 
powered by telltarget